Editing Wiki

Eine ältere Version des Dokuments wurde geladen! Beim Speichern wird eine neue Version des Dokuments mit diesem Inhalt erstellt.

====== Schleife ======

1. Angeblich gibt es in Gothic keine Programmschleifen. Das ist aber nicht ganz richtig, jedoch muss man dazu zwei Sachen kombinieren:
Zuerst braucht man einen Scripttrigger in der Welt (hier heißt er SCHLEIFE), der nach x Sekunden (0 = keine Verzögerung) einen Script ausführt (hier jetzt TestSchleife). Der Trigger kann irgendwo an einer unerreichbaren Stelle sein, es ist nur wichtig, dass er existiert, ein Visual braucht er auch nicht. Der Trigger muss aber unendlich oft ausführbar sein und sollte mind. 1 Sekunde Verzögerung (delay) haben, damit Gothic etwas Luft zum reagieren hat.
Als zweites brauchen wir eine Funktion, die nach Ablauf den Trigger wieder feuert:

<code>
var string msg;
var int x;
func void TestSchleife ()
    {
    msg = IntToString (x);
    PrintScreen (msg, -1, x,"font_old_10_white.tga",_TIME_MESSAGE_XPGAINED);
    x++;
    if (x <= 10)         //Schleifenbedingung formulieren, kann nach Bedarf auch wo anders in der Funktion stehen
        {
        Wld_SendTrigger ("SCHLEIFE");   //Funktion erneut aufrufen lassen => Schleife entsteht
        };
    };
</code>

2. Eine andere Möglichkeit 'Schleifen' zu implementieren ist die Verwendung von Rekursion (eine Funktion ruft sich selbst auf bis eine Abbruchbedingung erfüllt ist).
Dies hat den Vorteil, dass keine Trigger benötigt werden und das Ergebnis sofort zurückgegeben wird - ohne das Risiko, dass sich während der Laufzeit der Schleife etwas in der Welt geändert haben könnte.

<code>
func int Npc_GetTalentSkillSum( var C_Npc npc )
{
    // Lokale Variablen behalten in Daedalus ihren Wert
    // ( vergleichbar mit 'static' Variablen in C/C++ )
    var int tal;
    var int sum;

// Start - Summe initialisieren
    if ( 0 == tal )
    {
        sum = 0;
    };

// Berechnung - Talentstufe addieren
    sum += Npc_GetTalentSkill( npc, tal );

// Schrittweite - Index inkrementieren
    tal += 1;

// Rekursion - Abbruchbedingung
    if ( tal < NPC_TALENT_MAX )
    {
        Npc_GetTalentSkillSum( npc );
    };

// Ende - Index reinitialisieren
    tal = 0;

return sum;
};

/** /
    // Beispielaufruf

var int sum;
    sum = Npc_GetTalentSkillSum( hero );

var string text;
    text = ConcatStrings( "Gelernte Talentstufen: ", IntToString( sum ) );

PrintScreen ( text, -1, -1, FONT_Screen, 5 );	
/**/
</code>

Bitte löse folgende Gleichung um zu zeigen dass du ein Mensch bist. 92 +6 = ? Dieses Feld bitte leer lassen:

Zusammenfassung

Editing Wiki

Benutzer-Werkzeuge

Webseiten-Werkzeuge

Seiten-Werkzeuge